1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
|
;*****************************************************************************
;* x86-optimized functions for blend filter
;*
;* Copyright (C) 2015 Paul B Mahol
;* Copyright (C) 2018 Henrik Gramner
;* Copyright (C) 2018 Jokyo Images
;*
;* This file is part of FFmpeg.
;*
;* FFmpeg is free software; you can redistribute it and/or
;* modify it under the terms of the GNU Lesser General Public
;* License as published by the Free Software Foundation; either
;* version 2.1 of the License, or (at your option) any later version.
;*
;* FFmpeg is distributed in the hope that it will be useful,
;* but WITHOUT ANY WARRANTY; without even the implied warranty of
;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
;* Lesser General Public License for more details.
;*
;* You should have received a copy of the GNU Lesser General Public
;* License along with FFmpeg; if not, write to the Free Software
;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
;******************************************************************************
%include "libavutil/x86/x86util.asm"
SECTION_RODATA
ps_255: times 4 dd 255.0
pd_32768 : times 4 dd 32768
pd_65535 : times 4 dd 65535
pw_1: times 8 dw 1
pw_128: times 8 dw 128
pw_255: times 8 dw 255
pb_127: times 16 db 127
pb_128: times 16 db 128
pb_255: times 16 db 255
SECTION .text
%macro BLEND_INIT 2-3 0
%if ARCH_X86_64
cglobal blend_%1, 6, 9, %2, top, top_linesize, bottom, bottom_linesize, dst, dst_linesize, width, end, x
mov widthd, dword widthm
%if %3; is 16 bit
add widthq, widthq ; doesn't compile on x86_32
%endif
%else
cglobal blend_%1, 5, 7, %2, top, top_linesize, bottom, bottom_linesize, dst, end, x
%define dst_linesizeq r5mp
%define widthq r6mp
%endif
mov endd, dword r7m
add topq, widthq
add bottomq, widthq
add dstq, widthq
neg widthq
%endmacro
%macro BLEND_END 0
add topq, top_linesizeq
add bottomq, bottom_linesizeq
add dstq, dst_linesizeq
sub endd, 1
jg .nextrow
REP_RET
%endmacro
%macro BLEND_SIMPLE 2-3 0
BLEND_INIT %1, 2, %3
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
p%2 m0, m1
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
; %1 name , %2 src (b or w), %3 inter (w or d), %4 (1 if 16bit, not set if 8 bit)
%macro GRAINEXTRACT 3-4 0
BLEND_INIT %1, 6, %4
pxor m4, m4
%if %4 ; 16 bit
VBROADCASTI128 m5, [pd_32768]
%else
VBROADCASTI128 m5, [pw_128]
%endif
.nextrow:
mov xq, widthq
.loop:
movu m1, [topq + xq]
movu m3, [bottomq + xq]
punpckl%2%3 m0, m1, m4
punpckh%2%3 m1, m4
punpckl%2%3 m2, m3, m4
punpckh%2%3 m3, m4
padd%3 m0, m5
padd%3 m1, m5
psub%3 m0, m2
psub%3 m1, m3
packus%3%2 m0, m1
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
%macro MULTIPLY 3 ; a, b, pw_1
pmullw %1, %2 ; xxxxxxxx a * b
paddw %1, %3
psrlw %2, %1, 8
paddw %1, %2
psrlw %1, 8 ; 00xx00xx a * b / 255
%endmacro
%macro SCREEN 4 ; a, b, pw_1, pw_255
pxor %1, %4 ; 00xx00xx 255 - a
pxor %2, %4
MULTIPLY %1, %2, %3
pxor %1, %4 ; 00xx00xx 255 - x / 255
%endmacro
%macro BLEND_MULTIPLY 0
BLEND_INIT multiply, 6
pxor m4, m4
VBROADCASTI128 m5, [pw_1]
.nextrow:
mov xq, widthq
.loop:
movu m1, [topq + xq]
movu m3, [bottomq + xq]
punpcklbw m0, m1, m4
punpckhbw m1, m4
punpcklbw m2, m3, m4
punpckhbw m3, m4
MULTIPLY m0, m2, m5
MULTIPLY m1, m3, m5
packuswb m0, m1
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
%macro BLEND_SCREEN 0
BLEND_INIT screen, 7
pxor m4, m4
VBROADCASTI128 m5, [pw_1]
VBROADCASTI128 m6, [pw_255]
.nextrow:
mov xq, widthq
.loop:
movu m1, [topq + xq]
movu m3, [bottomq + xq]
punpcklbw m0, m1, m4
punpckhbw m1, m4
punpcklbw m2, m3, m4
punpckhbw m3, m4
SCREEN m0, m2, m5, m6
SCREEN m1, m3, m5, m6
packuswb m0, m1
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
;%1 name, %2 (b or w), %3 (set if 16 bit)
%macro AVERAGE 2-3 0
BLEND_INIT %1, 3, %3
pcmpeqb m2, m2
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
pxor m0, m2
pxor m1, m2
pavg%2 m0, m1
pxor m0, m2
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
; %1 name , %2 src (b or w), %3 inter (w or d), %4 (1 if 16bit, not set if 8 bit)
%macro GRAINMERGE 3-4 0
BLEND_INIT %1, 6, %4
pxor m4, m4
%if %4 ; 16 bit
VBROADCASTI128 m5, [pd_32768]
%else
VBROADCASTI128 m5, [pw_128]
%endif
.nextrow:
mov xq, widthq
.loop:
movu m1, [topq + xq]
movu m3, [bottomq + xq]
punpckl%2%3 m0, m1, m4
punpckh%2%3 m1, m4
punpckl%2%3 m2, m3, m4
punpckh%2%3 m3, m4
padd%3 m0, m2
padd%3 m1, m3
psub%3 m0, m5
psub%3 m1, m5
packus%3%2 m0, m1
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
%macro HARDMIX 0
BLEND_INIT hardmix, 5
VBROADCASTI128 m2, [pb_255]
VBROADCASTI128 m3, [pb_128]
VBROADCASTI128 m4, [pb_127]
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
pxor m1, m4
pxor m0, m3
pcmpgtb m1, m0
pxor m1, m2
movu [dstq + xq], m1
add xq, mmsize
jl .loop
BLEND_END
%endmacro
%macro DIVIDE 0
BLEND_INIT divide, 4
pxor m2, m2
mova m3, [ps_255]
.nextrow:
mov xq, widthq
.loop:
movd m0, [topq + xq] ; 000000xx
movd m1, [bottomq + xq]
punpcklbw m0, m2 ; 00000x0x
punpcklbw m1, m2
punpcklwd m0, m2 ; 000x000x
punpcklwd m1, m2
cvtdq2ps m0, m0
cvtdq2ps m1, m1
divps m0, m1 ; a / b
mulps m0, m3 ; a / b * 255
minps m0, m3
cvttps2dq m0, m0
packssdw m0, m0 ; 00000x0x
packuswb m0, m0 ; 000000xx
movd [dstq + xq], m0
add xq, mmsize / 4
jl .loop
BLEND_END
%endmacro
%macro PHOENIX 2-3 0
; %1 name, %2 b or w, %3 (opt) 1 if 16 bit
BLEND_INIT %1, 4, %3
VBROADCASTI128 m3, [pb_255]
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
mova m2, m0
pminu%2 m0, m1
pmaxu%2 m1, m2
mova m2, m3
psubus%2 m2, m1
paddus%2 m2, m0
movu [dstq + xq], m2
add xq, mmsize
jl .loop
BLEND_END
%endmacro
; %1 name , %2 src (b or w), %3 inter (w or d), %4 (1 if 16bit, not set if 8 bit)
%macro DIFFERENCE 3-4 0
BLEND_INIT %1, 5, %4
pxor m2, m2
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
punpckh%2%3 m3, m0, m2
punpckl%2%3 m0, m2
punpckh%2%3 m4, m1, m2
punpckl%2%3 m1, m2
psub%3 m0, m1
psub%3 m3, m4
%if %4; 16 bit
pabsd m0, m0
pabsd m3, m3
%else
ABS2 m0, m3, m1, m4
%endif
packus%3%2 m0, m3
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
; %1 name , %2 src (b or w), %3 inter (w or d), %4 (1 if 16bit, not set if 8 bit)
%macro EXTREMITY 3-4 0
BLEND_INIT %1, 8, %4
pxor m2, m2
%if %4; 16 bit
VBROADCASTI128 m4, [pd_65535]
%else
VBROADCASTI128 m4, [pw_255]
%endif
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
punpckh%2%3 m5, m0, m2
punpckl%2%3 m0, m2
punpckh%2%3 m6, m1, m2
punpckl%2%3 m1, m2
psub%3 m3, m4, m0
psub%3 m7, m4, m5
psub%3 m3, m1
psub%3 m7, m6
%if %4; 16 bit
pabsd m3, m3
pabsd m7, m7
%else
ABS2 m3, m7, m1, m6
%endif
packus%3%2 m3, m7
movu [dstq + xq], m3
add xq, mmsize
jl .loop
BLEND_END
%endmacro
%macro NEGATION 3-4 0
BLEND_INIT %1, 8, %4
pxor m2, m2
%if %4; 16 bit
VBROADCASTI128 m4, [pd_65535]
%else
VBROADCASTI128 m4, [pw_255]
%endif
.nextrow:
mov xq, widthq
.loop:
movu m0, [topq + xq]
movu m1, [bottomq + xq]
punpckh%2%3 m5, m0, m2
punpckl%2%3 m0, m2
punpckh%2%3 m6, m1, m2
punpckl%2%3 m1, m2
psub%3 m3, m4, m0
psub%3 m7, m4, m5
psub%3 m3, m1
psub%3 m7, m6
%if %4; 16 bit
pabsd m3, m3
pabsd m7, m7
%else
ABS2 m3, m7, m1, m6
%endif
psub%3 m0, m4, m3
psub%3 m1, m4, m7
packus%3%2 m0, m1
movu [dstq + xq], m0
add xq, mmsize
jl .loop
BLEND_END
%endmacro
INIT_XMM sse2
BLEND_SIMPLE xor, xor
BLEND_SIMPLE or, or
BLEND_SIMPLE and, and
BLEND_SIMPLE addition, addusb
BLEND_SIMPLE subtract, subusb
BLEND_SIMPLE darken, minub
BLEND_SIMPLE lighten, maxub
GRAINEXTRACT grainextract, b, w
BLEND_MULTIPLY
BLEND_SCREEN
AVERAGE average, b
GRAINMERGE grainmerge, b, w
HARDMIX
PHOENIX phoenix, b
DIFFERENCE difference, b, w
DIVIDE
EXTREMITY extremity, b, w
NEGATION negation, b, w
%if ARCH_X86_64
BLEND_SIMPLE addition_16, addusw, 1
BLEND_SIMPLE and_16, and, 1
BLEND_SIMPLE or_16, or, 1
BLEND_SIMPLE subtract_16, subusw, 1
BLEND_SIMPLE xor_16, xor, 1
AVERAGE average_16, w, 1
%endif
INIT_XMM ssse3
DIFFERENCE difference, b, w
EXTREMITY extremity, b, w
NEGATION negation, b, w
INIT_XMM sse4
%if ARCH_X86_64
BLEND_SIMPLE darken_16, minuw, 1
BLEND_SIMPLE lighten_16, maxuw, 1
GRAINEXTRACT grainextract_16, w, d, 1
GRAINMERGE grainmerge_16, w, d, 1
PHOENIX phoenix_16, w, 1
DIFFERENCE difference_16, w, d, 1
EXTREMITY extremity_16, w, d, 1
NEGATION negation_16, w, d, 1
%endif
%if HAVE_AVX2_EXTERNAL
INIT_YMM avx2
BLEND_SIMPLE xor, xor
BLEND_SIMPLE or, or
BLEND_SIMPLE and, and
BLEND_SIMPLE addition, addusb
BLEND_SIMPLE subtract, subusb
BLEND_SIMPLE darken, minub
BLEND_SIMPLE lighten, maxub
GRAINEXTRACT grainextract, b, w
BLEND_MULTIPLY
BLEND_SCREEN
AVERAGE average, b
GRAINMERGE grainmerge, b, w
HARDMIX
PHOENIX phoenix, b
DIFFERENCE difference, b, w
EXTREMITY extremity, b, w
NEGATION negation, b, w
%if ARCH_X86_64
BLEND_SIMPLE addition_16, addusw, 1
BLEND_SIMPLE and_16, and, 1
BLEND_SIMPLE darken_16, minuw, 1
BLEND_SIMPLE lighten_16, maxuw, 1
BLEND_SIMPLE or_16, or, 1
BLEND_SIMPLE subtract_16, subusw, 1
BLEND_SIMPLE xor_16, xor, 1
GRAINEXTRACT grainextract_16, w, d, 1
AVERAGE average_16, w, 1
GRAINMERGE grainmerge_16, w, d, 1
PHOENIX phoenix_16, w, 1
DIFFERENCE difference_16, w, d, 1
EXTREMITY extremity_16, w, d, 1
NEGATION negation_16, w, d, 1
%endif
%endif
|
